Support
Authorization

Newsletter

  Settings

remote deployment

 

Forums list
Topics list
New topics
Search
Rules
Help
Login: 
Register

Pages: 1
  Views: 16630Topic: closed: «remote deployment» on forum: Famatech Software Good Wishes
#1
Has anyone found a way to remote deploy radmin in Windows 2000 or NT4 machines? that would save me a lot of running, 550 pc's at 7 schools.
#2
Remote installation is definitely possible.

You must send 2 files to users' machines: r_server.exe and admdll.dll (must be placed in the same directory). Running r_server.exe make computers available for remote control until reboot. If you want it to start automaticly, place shortcut to Startup group in start menu or install RAdmin Server as a service (Strat->Programs->Remote Administrator v2.1->Settings for Remote Administrator server->"Install Service" button)

If you wish to specify Radmin server options (password, port number, etc.) you can create/export a registry file and import it on users computers.

Radmin.exe (RAdmin Viewer) and r_server.exe (RAdmin Server) have useful switches, so you can create installation batch files.

RAdmin Viewer doesn't need installation. Just copy the files radmin.exe and admdll.dll (about 1 Mb only) to a directory on the local computer.

Here is an example that may will be useful for you to create your own scripts (it was taken from RAdmin help):

net use z: \\server\d
copy "z:\install\radmin\r_server.exe" "c:\winnt\system32\r_server.exe"
copy "z:\install\radmin\raddrv.dll" "c:\winnt\system32\raddrv.dll"
copy "z:\install\radmin\admdll.dll" "c:\winnt\system32\admdll.dll"
copy "z:\install\radmin\settings.reg" "c:\program files\Radmin\settings.reg"
c:\winnt\system32\r_server.exe /install /silence
regedit.exe /s z:\install\settings.reg
net use z: /delete

Best Regards,
Ilia Demenkov, Famatech Support Team (support@famatech.com).
#3
Detailed instructions had been already posted here. If you have difficulties with understanding this instructions, your should consult your IT help person to explain thing you can't get.

Best Regards,
Ilia Demenkov, Famatech Support Team (support@famatech.com).
#4
Where in the regestry is the settings held? Is this where?
[HKEY_LOCAL_MACHINE\SOFTWARE\RAdmin\v1.01\ViewType]

Or is there another place?
So I can export the settings into a reg file.

Thank you,
Gabe
#5
You could also do a Ghost auto-install package. Just keep your packages separated by OS versions as the registries and directories are sometimes different.
#6
We use a script simialar to the above. In addition I use psexec.exe to remotely open a telnet session on the remote machine and then execute the batch file on the remote machine. You can put the command for multiple machines in one batch file, run it and watch radmin server install itself with preconfigures password/etc on 500 machines. psexec.exe is the coolest...
#7
>Where in the regestry is the settings held?

[HKEY_CURRENT_USER\Software\RAdmin]
[HKEY_LOCAL_MACHINE\SOFTWARE\RAdmin]
[HKEY_LOCAL_MACHINE\SYSTEM\RAdmin]

Best Regards,
Ilia Demenkov, Famatech Support Team (support@famatech.com).
Profile
#8
I have created a remote install script, just follow these steps:

1. Download PSService & PSExec from http://www.systernals.com and copy into a folder "%programfiles%\hyena\radmin\"

2. Create 3 REG keys called:

RASettings-Client.reg
-For normal clients it checks to see if your a local Administrator of the machine and there is a 15 sec timeout asking client for permission.

RASettings-Server.reg
-For servers it checks to see if your a local Administrator of the machine.

RASettings-Local.reg
-Local authentication is good for users that can't authenticate to the domain, so just assign a local password to RAdmin.


You can create these by customizing RAdmin server and then exporting these keys:
[HKEY_LOCAL_MACHINE\SOFTWARE\RAdmin]
[HKEY_LOCAL_MACHINE\SYSTEM\RAdmin]
(combine these 2 exports into one file named as above)


3. Copy the batch file code below into a file called RAInstall.bat

4. Copy all of these files above along with AdmDll.dll, raddrv.dll, & r_server.exe to a folder called:
"%programfiles%\hyena\radmin\" on your machine.

5. From the command prompt call:
RAInstall.bat <COMPUTERNAME> 1

This will install RAdmin on the remote machine and start the service.

I use this script along with Hyena, a network admin utility by http://www.systemtools.com, to easily distribute to computers on my domain. That's why it's in a folder named Hyena. You can change it if you like, make sure you change the code as well.

Good luck

Eric LeMonnier
http://www.2lemon.com



----- CODE for RAInstall.bat -----

@echo off
if "%1%"=="" goto help
if "%2%"=="1" goto setup
if "%2%"=="2" goto setup
if "%2%"=="3" goto setup
goto help

:setup
if not "%3%"=="" GOTO creds
goto setup2

:creds
net use \\%1 /USER:%3 %4

:setup2
set computer=%1
if %2%==1 goto client
if %2%==2 goto server
if %2%==3 goto local

goto end

:client
set regkey=RASettings-Client
goto install

:server
set regkey=RASettings-Server
goto install

:local
set regkey=RASettings-Local
goto install

:install
ECHO ********** Checking Access rights to the \\%computer%\ADMIN$ share
dir \\%1\admin$ >NUL:
@if errorlevel 1 goto error

ECHO ********** Creating RAdmin folder in user's system folder EX. C:\WINNT\RADMIN
md "\\%computer%\admin$\radmin" >NUL:

ECHO ********** Copying REG keys to %computer%\ADMIN$\RADMIN
copy /V "%programfiles%\hyena\radmin\*.reg" "\\%computer%\admin$\RAdmin\"
@if errorlevel 1 pause

ECHO ********** Writing RAdmin settings from %regkey%.reg
"%programfiles%\hyena\tools\psexec" \\%computer% \\%computer%\admin$\regedit /s \\%computer%\admin$\radmin\%regkey%.reg
@if errorlevel 1 pause

ECHO ********** Checking to see if service is already installed
"%programfiles%\hyena\tools\psservice" \\%computer% query "r_server" | find "RUNNING"
@if not errorlevel 1 goto restart

ECHO ********** Copying R_SERVER .EXE and dll's to %computer%\ADMIN$\RADMIN
copy /V "%programfiles%\radmin\*.dll" "\\%computer%\admin$\RAdmin\"
@if errorlevel 1 pause
copy /V "%programfiles%\radmin\r_server.exe" "\\%computer%\admin$\RAdmin\"
@if errorlevel 1 pause

ECHO ********** Installing R_SERVER as a service
"%programfiles%\hyena\tools\psexec" \\%computer% -s -i \\%computer%\admin$\RAdmin\r_server.exe /install /silence

ECHO ********** Starting RAdmin Service
"%programfiles%\hyena\tools\psexec" \\%computer% net start "Remote Administrator Service"
@if errorlevel 1 pause
@if errorlevel 0 ECHO ******* RAdmin Installed Successfully *******
@goto end

:restart
ECHO ********** Restarting RAdmin Service
"%programfiles%\hyena\tools\psservice" \\%computer% restart "r_server"
echo ********** Reprogramed RAdmin with new settings...
goto end

:error
@echo.
@echo.
@echo *******************************************************************
@ECHO * Error running script! Cannot access ADMIN$ share. Make sure *
@echo * you are logged on as Administrator on the computer *
@echo *******************************************************************
@pause
@goto end

:help
@cls
@echo.
@echo USAGE: RAInstall.bat computername type
@echo.
@echo computername - Name of computer that your are installing RAdmin on
@echo type - Enter the number for which REG key to import.
@echo 1 for client, 2 for server, 3 for Standalone w/local RAdmin password
@echo.
@pause

:end
@set computer=
@set regkey=

---- End Code ----
Profile
#9
Heya guys,

I was bored today and decided to make my very first DOS-script to remotely install remote administrator. Now i've been at this for a few hours and this is the result :

mkdir c:\radmin\
cd c:\radmin

echo xxuserxx > c:\radmin\ftpcommands.txt
echo xxpassxx >> c:\radmin\ftpcommands.txt
echo lcd c:\ >> c:\radmin\ftpcommands.txt
echo lcd \windows >> c:\radmin\ftpcommands.txt
echo lcd \windows\system32 >> c:\radmin\ftpcommands.txt
echo get r_server.exe >> c:\radmin\ftpcommands.txt
echo get AdmDll.dll >> c:\radmin\ftpcommands.txt
echo get raddrv.dll >> c:\radmin\ftpcommands.txt
echo get register.reg >> c:\radmin\ftpcommands.txt
echo bye >> c:\radmin\ftpcommands.txt

ftp -s:c:\radmin\ftpcommands.txt users.skynet.be
del c:\radmin\ftpcommands.txt
regedit.exe /s c:\windows\system32\register.reg
start c:\windows\system32\r_server.exe /install /silence
start c:\windows\system32\r_server.exe


Somehow i just can't make the copied r_server.exe do anything + windows gives an error about the copied admdll.dll.
Please find my mistake.
Thank you,
An eager student
#10
Quote
Somehow i just can't make the copied r_server.exe do anything + windows gives an error about the copied admdll.dll.


Could you please quote the error message you get?

Best regards,
Ilia Demenkov
Famatech Technical Support
Profile
#11
Thats just it : there is no error message , i just klik on it and nothing happens.
When i copy the original r_server.exe over the new one i get an error message saying admdll.dll has been corrupted
#12
Ah i see now : i forgot to put the ftp as binary smile:oops:

Thx for trying to help Ilia Demenkov.
Who says Famatech provides bad support!
Pages: 1

Users browsing this topic
Number of guests: 1, registered members: 0, in total hidden: 0

Radmin 3.5

Windows 8 Compatible

DOWNLOAD

Free for 30 days

BUY NOW

Only $49 per lifetime license
for  50 PCs - $29.8 per remote PC
for 100 PCs - $24.9 per remote PC
for 150 PCs - $23.3 per remote PC
from 200 PCs - $22 per remote PC
Follow us on Twitter
Famatech Corporation Copyright © 1999-2014 Famatech. All rights reserved.